process MLST {
    tag "$meta.id"
    label 'process_micro'

    module (params.enable_module ? "${params.swmodulepath}${params.fs}mlst${params.fs}2.23.0" : null)
    conda (params.enable_conda ? "conda-forge::perl bioconda::mlst=2.23.0" : null)
    container "${ workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container ?
        'https://depot.galaxyproject.org/singularity/mlst:2.23.0--hdfd78af_1' :
        'quay.io/biocontainers/mlst:2.23.0--hdfd78af_1' }"

    input:
    tuple val(meta), path(fasta), path(datadir)

    output:
    tuple val(meta), path("*.tsv"), emit: tsv
    path "versions.yml"           , emit: versions

    when:
    (task.ext.when == null || task.ext.when) && fasta.size() > 0

    script:
    def args = task.ext.args ?: ''
    def prefix = (task.ext.prefix ?: "${meta.id}") + (task.index ?: '')
    def label = (params.mlst_label ? "--label '${prefix}'" : '')
    args += (datadir ? " --datadir  '.' " : '')
    """
    mlst \\
        --threads $task.cpus \\
        $label \\
        $args \\
        $fasta > ${prefix}.tsv

    cat <<-END_VERSIONS > versions.yml
    "${task.process}":
        mlst: \$( echo \$(mlst --version 2>&1) | sed 's/mlst //' )
    END_VERSIONS
    """

}