Mercurial > repos > rliterman > csp2

comparison CSP2/CSP2_env/env-d9b9114564458d9d-741b3de822f2aaca6c6caa4325c4afce/share/aclocal/progtest.m4 @ 68:5028fdace37b

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
planemo upload commit 2e9511a184a1ca667c7be0c6321a36dc4e3d116d
author jpayne
date Tue, 18 Mar 2025 16:23:26 -0400
parents
children
comparison
equal deleted inserted replaced
67:0e9998148a16 68:5028fdace37b
1 # progtest.m4 serial 10 (gettext-0.23)
2 dnl Copyright (C) 1996-2003, 2005, 2008-2024 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6 dnl
7 dnl This file can be used in projects which are not available under
8 dnl the GNU General Public License or the GNU Lesser General Public
9 dnl License but which still want to provide support for the GNU gettext
10 dnl functionality.
11 dnl Please note that the actual code of the GNU gettext library is covered
12 dnl by the GNU Lesser General Public License, and the rest of the GNU
13 dnl gettext package is covered by the GNU General Public License.
14 dnl They are *not* in the public domain.
15
16 dnl Authors:
17 dnl Ulrich Drepper <drepper@cygnus.com>, 1996.
18
19 AC_PREREQ([2.53])
20
21 # Search path for a program which passes the given test.
22
23 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
24 dnl TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
25 AC_DEFUN([AM_PATH_PROG_WITH_TEST],
26 [
27 # Prepare PATH_SEPARATOR.
28 # The user is always right.
29 if test "${PATH_SEPARATOR+set}" != set; then
30 # Determine PATH_SEPARATOR by trying to find /bin/sh in a PATH which
31 # contains only /bin. Note that ksh looks also at the FPATH variable,
32 # so we have to set that as well for the test.
33 PATH_SEPARATOR=:
34 (PATH='/bin;/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
35 && { (PATH='/bin:/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
36 || PATH_SEPARATOR=';'
37 }
38 fi
39
40 # Find out how to test for executable files. Don't use a zero-byte file,
41 # as systems may use methods other than mode bits to determine executability.
42 cat >conf$$.file <<_ASEOF
43 #! /bin/sh
44 exit 0
45 _ASEOF
46 chmod +x conf$$.file
47 if test -x conf$$.file >/dev/null 2>&1; then
48 ac_executable_p="test -x"
49 else
50 ac_executable_p="test -f"
51 fi
52 rm -f conf$$.file
53
54 # Extract the first word of "$2", so it can be a program name with args.
55 set dummy $2; ac_word=[$]2
56 AC_MSG_CHECKING([for $ac_word])
57 AC_CACHE_VAL([ac_cv_path_$1],
58 [case "[$]$1" in
59 [[\\/]]* | ?:[[\\/]]*)
60 ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
61 ;;
62 *)
63 gt_saved_IFS="$IFS"; IFS=$PATH_SEPARATOR
64 for ac_dir in m4_if([$5], , $PATH, [$5]); do
65 IFS="$gt_saved_IFS"
66 test -z "$ac_dir" && ac_dir=.
67 for ac_exec_ext in '' $ac_executable_extensions; do
68 if $ac_executable_p "$ac_dir/$ac_word$ac_exec_ext"; then
69 echo "$as_me: trying $ac_dir/$ac_word..." >&AS_MESSAGE_LOG_FD
70 if [$3]; then
71 ac_cv_path_$1="$ac_dir/$ac_word$ac_exec_ext"
72 break 2
73 fi
74 fi
75 done
76 done
77 IFS="$gt_saved_IFS"
78 dnl If no 4th arg is given, leave the cache variable unset,
79 dnl so AC_PATH_PROGS will keep looking.
80 m4_if([$4], , , [ test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
81 ])dnl
82 ;;
83 esac])dnl
84 $1="$ac_cv_path_$1"
85 if test m4_if([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
86 AC_MSG_RESULT([$][$1])
87 else
88 AC_MSG_RESULT([no])
89 fi
90 AC_SUBST([$1])dnl
91 ])