Mercurial > repos > rliterman > csp2

annotate CSP2/CSP2_env/env-d9b9114564458d9d-741b3de822f2aaca6c6caa4325c4afce/lib/cmake/CapnProto/CapnProtoMacros.cmake @ 69:33d812a61356

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
planemo upload commit 2e9511a184a1ca667c7be0c6321a36dc4e3d116d
author jpayne
date Tue, 18 Mar 2025 17:55:14 -0400
parents
children
rev   line source
jpayne@69 1 # CAPNP_GENERATE_CPP ===========================================================
jpayne@69 2 #
jpayne@69 3 # Example usage:
jpayne@69 4 # find_package(CapnProto)
jpayne@69 5 # capnp_generate_cpp(CAPNP_SRCS CAPNP_HDRS schema.capnp)
jpayne@69 6 # add_executable(foo main.cpp ${CAPNP_SRCS})
jpayne@69 7 # target_link_libraries(foo PRIVATE CapnProto::capnp-rpc)
jpayne@69 8 # target_include_directories(foo PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
jpayne@69 9 #
jpayne@69 10 # If you are not using the RPC features you can use 'CapnProto::capnp' in the
jpayne@69 11 # target_link_libraries call
jpayne@69 12 #
jpayne@69 13 # Configuration variables (optional):
jpayne@69 14 # CAPNPC_OUTPUT_DIR
jpayne@69 15 # Directory to place compiled schema sources (default: CMAKE_CURRENT_BINARY_DIR).
jpayne@69 16 # CAPNPC_IMPORT_DIRS
jpayne@69 17 # List of additional include directories for the schema compiler.
jpayne@69 18 # (CAPNPC_SRC_PREFIX and CAPNP_INCLUDE_DIRECTORY are always included.)
jpayne@69 19 # CAPNPC_SRC_PREFIX
jpayne@69 20 # Schema file source prefix (default: CMAKE_CURRENT_SOURCE_DIR).
jpayne@69 21 # CAPNPC_FLAGS
jpayne@69 22 # Additional flags to pass to the schema compiler.
jpayne@69 23 #
jpayne@69 24 # TODO: convert to cmake_parse_arguments
jpayne@69 25
jpayne@69 26 function(CAPNP_GENERATE_CPP SOURCES HEADERS)
jpayne@69 27 if(NOT ARGN)
jpayne@69 28 message(SEND_ERROR "CAPNP_GENERATE_CPP() called without any source files.")
jpayne@69 29 endif()
jpayne@69 30 set(tool_depends ${EMPTY_STRING})
jpayne@69 31 #Use cmake targets available
jpayne@69 32 if(TARGET capnp_tool)
jpayne@69 33 if(NOT CAPNP_EXECUTABLE)
jpayne@69 34 set(CAPNP_EXECUTABLE $<TARGET_FILE:capnp_tool>)
jpayne@69 35 endif()
jpayne@69 36 if(NOT CAPNPC_CXX_EXECUTABLE)
jpayne@69 37 get_target_property(CAPNPC_CXX_EXECUTABLE capnpc_cpp CAPNPC_CXX_EXECUTABLE)
jpayne@69 38 endif()
jpayne@69 39 if(NOT CAPNP_INCLUDE_DIRECTORY)
jpayne@69 40 get_target_property(CAPNP_INCLUDE_DIRECTORY capnp_tool CAPNP_INCLUDE_DIRECTORY)
jpayne@69 41 endif()
jpayne@69 42 list(APPEND tool_depends capnp_tool capnpc_cpp)
jpayne@69 43 endif()
jpayne@69 44 if(NOT CAPNP_EXECUTABLE)
jpayne@69 45 message(SEND_ERROR "Could not locate capnp executable (CAPNP_EXECUTABLE).")
jpayne@69 46 endif()
jpayne@69 47 if(NOT CAPNPC_CXX_EXECUTABLE)
jpayne@69 48 message(SEND_ERROR "Could not locate capnpc-c++ executable (CAPNPC_CXX_EXECUTABLE).")
jpayne@69 49 endif()
jpayne@69 50 if(NOT CAPNP_INCLUDE_DIRECTORY)
jpayne@69 51 message(SEND_ERROR "Could not locate capnp header files (CAPNP_INCLUDE_DIRECTORY).")
jpayne@69 52 endif()
jpayne@69 53
jpayne@69 54 if(DEFINED CAPNPC_OUTPUT_DIR)
jpayne@69 55 # Prepend a ':' to get the format for the '-o' flag right
jpayne@69 56 set(output_dir ":${CAPNPC_OUTPUT_DIR}")
jpayne@69 57 else()
jpayne@69 58 set(output_dir ":.")
jpayne@69 59 endif()
jpayne@69 60
jpayne@69 61 if(NOT DEFINED CAPNPC_SRC_PREFIX)
jpayne@69 62 set(CAPNPC_SRC_PREFIX "${CMAKE_CURRENT_SOURCE_DIR}")
jpayne@69 63 endif()
jpayne@69 64 get_filename_component(CAPNPC_SRC_PREFIX "${CAPNPC_SRC_PREFIX}" ABSOLUTE)
jpayne@69 65
jpayne@69 66 # Default compiler includes. Note that in capnp's own test usage of capnp_generate_cpp(), these
jpayne@69 67 # two variables will end up evaluating to the same directory. However, it's difficult to
jpayne@69 68 # deduplicate them because if CAPNP_INCLUDE_DIRECTORY came from the capnp_tool target property,
jpayne@69 69 # then it must be a generator expression in order to handle usages in both the build tree and the
jpayne@69 70 # install tree. This vastly overcomplicates duplication detection, so the duplication doesn't seem
jpayne@69 71 # worth fixing.
jpayne@69 72 set(include_path -I "${CAPNPC_SRC_PREFIX}" -I "${CAPNP_INCLUDE_DIRECTORY}")
jpayne@69 73
jpayne@69 74 if(DEFINED CAPNPC_IMPORT_DIRS)
jpayne@69 75 # Append each directory as a series of '-I' flags in ${include_path}
jpayne@69 76 foreach(directory ${CAPNPC_IMPORT_DIRS})
jpayne@69 77 get_filename_component(absolute_path "${directory}" ABSOLUTE)
jpayne@69 78 list(APPEND include_path -I "${absolute_path}")
jpayne@69 79 endforeach()
jpayne@69 80 endif()
jpayne@69 81
jpayne@69 82 set(${SOURCES})
jpayne@69 83 set(${HEADERS})
jpayne@69 84 foreach(schema_file ${ARGN})
jpayne@69 85 get_filename_component(file_path "${schema_file}" ABSOLUTE)
jpayne@69 86 get_filename_component(file_dir "${file_path}" PATH)
jpayne@69 87 if(NOT EXISTS "${file_path}")
jpayne@69 88 message(FATAL_ERROR "Cap'n Proto schema file '${file_path}' does not exist!")
jpayne@69 89 endif()
jpayne@69 90
jpayne@69 91 # Figure out where the output files will go
jpayne@69 92 if (NOT DEFINED CAPNPC_OUTPUT_DIR)
jpayne@69 93 set(CAPNPC_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/")
jpayne@69 94 endif()
jpayne@69 95 # Output files are placed in CAPNPC_OUTPUT_DIR, at a location as if they were
jpayne@69 96 # relative to CAPNPC_SRC_PREFIX.
jpayne@69 97 string(LENGTH "${CAPNPC_SRC_PREFIX}" prefix_len)
jpayne@69 98 string(SUBSTRING "${file_path}" 0 ${prefix_len} output_prefix)
jpayne@69 99 if(NOT "${CAPNPC_SRC_PREFIX}" STREQUAL "${output_prefix}")
jpayne@69 100 message(SEND_ERROR "Could not determine output path for '${schema_file}' ('${file_path}') with source prefix '${CAPNPC_SRC_PREFIX}' into '${CAPNPC_OUTPUT_DIR}'.")
jpayne@69 101 endif()
jpayne@69 102
jpayne@69 103 string(SUBSTRING "${file_path}" ${prefix_len} -1 output_path)
jpayne@69 104 set(output_base "${CAPNPC_OUTPUT_DIR}${output_path}")
jpayne@69 105
jpayne@69 106 add_custom_command(
jpayne@69 107 OUTPUT "${output_base}.c++" "${output_base}.h"
jpayne@69 108 COMMAND "${CAPNP_EXECUTABLE}"
jpayne@69 109 ARGS compile
jpayne@69 110 -o ${CAPNPC_CXX_EXECUTABLE}${output_dir}
jpayne@69 111 --src-prefix ${CAPNPC_SRC_PREFIX}
jpayne@69 112 ${include_path}
jpayne@69 113 ${CAPNPC_FLAGS}
jpayne@69 114 ${file_path}
jpayne@69 115 DEPENDS "${schema_file}" ${tool_depends}
jpayne@69 116 COMMENT "Compiling Cap'n Proto schema ${schema_file}"
jpayne@69 117 VERBATIM
jpayne@69 118 )
jpayne@69 119
jpayne@69 120 list(APPEND ${SOURCES} "${output_base}.c++")
jpayne@69 121 list(APPEND ${HEADERS} "${output_base}.h")
jpayne@69 122 endforeach()
jpayne@69 123
jpayne@69 124 set_source_files_properties(${${SOURCES}} ${${HEADERS}} PROPERTIES GENERATED TRUE)
jpayne@69 125 set(${SOURCES} ${${SOURCES}} PARENT_SCOPE)
jpayne@69 126 set(${HEADERS} ${${HEADERS}} PARENT_SCOPE)
jpayne@69 127 endfunction()